If you haven't yet done so, download and install the Microsoft Office 2003 Web Services Toolkit.

Start Access 2003 and create an unbound form named frmSplitCalculator.

Add the controls listed in Table 17-2 to the form. Size the controls to your liking.

From the VBA editor, select Tools Web Service References.... This menu item is added to the VBA editor by the Microsoft Office 2003 Web Services Toolkit.

At the Microsoft Office 2003 Web Services Toolkit dialog box, select the Web Service URL radio button and enter the following URL into the URL textbox:

www.deeptraining.com/webservices/runnercalculator.asmx

The RunnerCalculator service and its methods should be displayed in the SearchResults box. Check the checkbox to the left of RunnerCalculator and click the Add button at the bottom of the dialog box to add a reference to the RunnerCalculator service.

The toolkit adds a new class module to the project with the name clsws_RunnerCalculator. This class serves as a proxy for making calls to the web service. The code in this class will take care of speaking to the web service using the SOAP protocol.

Attach the following code to the cmdCalculateSplits button's Click event to use the clsws_RunnerCalculator proxy class to call the GetMileSplits method:

Private Sub cmdCalculateSplits_Click( )
    Dim prxRunnerCalc As clsws_RunnerCalculator
    Dim nlDS As MSXML2.IXMLDOMNodeList
    Dim i As Integer
    
    ' Clear any existing items from the listbox
    For i = lstSplits.ListCount - 1 To 0 Step -1
        lstSplits.RemoveItem (i)
    Next
    
    ' Add the headings to the list
    lstSplits.ColumnWidths = "0.35"";1"""
    lstSplits.ColumnHeads = True
    lstSplits.AddItem ("Mile;Split")
    
    On Error GoTo HandleErr
    DoCmd.Hourglass True
    
    ' Instantiate proxy class
    Set prxRunnerCalc = New clsws_RunnerCalculator
    
    If Len(txtDistance) > 0 And Len(txtHours) > 0 And _
     Len(txtMinutes) > 0 And Len(txtSeconds) > 0 Then
        ' Call GetMileSpilts method via proxy class
        ' This method returns a .NET DataSet which gets
        ' serializedd into XML.
        ' XML is returned by the proxy as the type
        ' MSXML2.IXMLDOMNodeList.
        Set nlDS = prxRunnerCalc.wsm_GetMileSplits(txtDistance, _
         txtHours, txtMinutes, txtSeconds)
         
        Call ProcessSplits(nlDS)
    Else
        MsgBox "You must enter values for each text box.", _
         vbOKOnly + vbCritical, "Splits Calculator"
    End If
    
ExitHere:
        On Error GoTo 0
        DoCmd.Hourglass False
        Exit Sub
        
HandleErr:
    MsgBox "Error " & Err.Number & ": " & Err.Description, _
        vbOKOnly + vbCritical, "Splits Calculator"
    Resume ExitHere
End Sub

Add the following code to the module to use the MSXML component to process the returned XML data and add the split values to the lstSplits listbox:

Private Sub ProcessSplits(nlDS As MSXML2.IXMLDOMNodeList)
    Dim nlPace As MSXML2.IXMLDOMNodeList
    Dim nodData As MSXML2.IXMLDOMNode
    Dim nodRow As MSXML2.IXMLDOMNode
    Dim nodField As MSXML2.IXMLDOMNode
    Dim strItem As String
    
    On Error GoTo HandleErr
    
    ' Grab the second node -- the data -- from the
    ' returned node list
    Set nodData = nlDS.Item(1)
    
    ' Get the Pace nodes (rows)
    Set nlPace = nodData.selectNodes("//MileSplits/Pace")
    ' For each Pace node
    For Each nodRow In nlPace
        ' Get the child nodes of Pace, i.e., the fields
        For Each nodField In nodRow.childNodes
            Select Case nodField.nodeName
                Case "Mile"
                    ' Grab the Mile value
                    strItem = nodField.nodeTypedValue
                Case "SplitString"
                    ' Grab the SplitString value
                    strItem = strItem & ";" & nodField.nodeTypedValue
                    ' Add the strItem value to the listbox
                    lstSplits.AddItem strItem
            End Select
        Next
    Next
    
ExitHere:
        On Error GoTo 0
        DoCmd.Hourglass False
        Exit Sub
        
HandleErr:
    MsgBox "Error " & Err.Number & ": " & Err.Description, _
        vbOKOnly + vbCritical, "Process Splits"
    Resume ExitHere
End Sub

Save and open the form to test it out. Enter values into each of the textboxes and click on the Calculate Splits button. The form should look similar to the one shown in Figure 17-8.