Syntax

set myRef to a ref to (file 1)

Synonyms

[a] ref to

Return value

reference

Description

You can set the variable on the left of this operator to a reference to the object or value on its right. The variable is then "pointing" to this object or value. For example, if you tell the Finder to:

set myRef to a ref to file 1

then myRef will refer to the first file on the desktop. If file 1 on the desktop changes, then myRef will still refer to file 1, even if that file is now different from the first one. This is best illustrated by the code in the following Examples section.

The script in the Examples section first creates a variable called myRef and sets it to the first file on the desktop. That file is then moved into a different folder; in other words, it is no longer the first file on the desktop. Another file now has that distinction. Since myRef was set to:

a reference to file 1

it now refers to the new file 1 (the old file 1 was moved into a different folder). As indicated by testing the:

name of myRef

a second time, myRef now points to a different file. This operator could be used in scripts that necessitate a variable that always points to a certain location in a container, such as to the last record in a database. Even though the database may change (records are dynamically deleted and added), you can always get information about the last record, such as its id number, because you have a variable that points to that position in the database, not just to a particular record.

Examples

tell application "Finder"
   set myRef to a ref to file 1
   set f1 to name of myRef
   log f1 -- look at value of the variable in Event Log window
   move file 1 to folder "today" (* original file 1 is now in a different 
location *)
   set f2 to name of myRef
   log f2 -- look at value of the variable in Event Log window
end tell